9.3.1. Problem

9.3.2. Solution

use File::Copy;
copy($oldfile, $newfile);

You can do it by hand:

open(IN,  "<", $oldfile)                    or die "can't open $oldfile: $!";
open(OUT, ">", $newfile)                    or die "can't open $newfile: $!";

$blksize = (stat IN)[11] || 16384;          # preferred block size?
while (1) {
    $len = sysread IN, $buf, $blksize);
    if (!defined $len) {
        next if $! =~ /^Interrupted/;       # ^Z and fg on EINTR
        die "System read error: $!\n";
    }
    last unless $len;

    $offset = 0;
    while ($len) {          # Handle partial writes.
        defined($written = syswrite OUT, $buf, $len, $offset)
            or die "System write error: $!\n";
        $len    -= $written;
        $offset += $written;
    };
}

close(IN);
close(OUT);

or you can call your system's copy program:

system("cp $oldfile $newfile");       # unix
system("copy $oldfile $newfile");     # dos, vms

9.3.3. Discussion

use File::Copy;

copy("datafile.dat", "datafile.bak")
    or die "copy failed: $!";

move("datafile.dat", "datafile.new")
    or die "move failed: $!";

Because these functions return only a simple success status, you can't easily tell which file prevented the copy or move from working. Copying the files manually lets you pinpoint which files didn't copy, but it fills your program with complex sysread s and syswrite s.