Example 6-10. urlify

  #!/usr/bin/perl
  # urlify - wrap HTML links around URL-like constructs
  $protos = '(http|telnet|gopher|file|wais|ftp)';
  $ltrs   = '\w';
  $gunk   = ';/#~:.?+=&%@!\-';
  $punc   = '.:?\-';
  $any    = "${ltrs}${gunk}${punc}";
  while (<>) {
      s{
        \b                    # start at word boundary
        (                     # begin $1  {
         $protos   :          # need resource and a colon
         [$any] +?            # followed by on or more
                              #  of any valid character, but
                              #  be conservative and take only
                              #  what you need to....
        )                     # end   $1  }
        (?=                   # look-ahead non-consumptive assertion
         [$punc]*             # either 0 or more punctuation
         [^$any]              #   followed by a non-url char
         |                    # or else
         $                    #   then end of the string
      )
     }{<A HREF="$1">$1</A>}igox;
    print;
  }